project(lws-minimal-secure-streams-stress C)
cmake_minimum_required(VERSION 3.10)
find_package(libwebsockets CONFIG REQUIRED)
list(APPEND CMAKE_MODULE_PATH ${LWS_CMAKE_DIR})
include(CheckCSourceCompiles)
include(LwsCheckRequirements)

set(SAMP lws-minimal-secure-streams-stress)

set(requirements 1)
require_lws_config(LWS_ROLE_H1 1 requirements)
require_lws_config(LWS_WITHOUT_CLIENT 0 requirements)
require_lws_config(LWS_WITH_SECURE_STREAMS 1 requirements)
require_lws_config(LWS_WITH_SECURE_STREAMS_STATIC_POLICY_ONLY 0 requirements)
require_lws_config(LWS_WITH_SYS_STATE 1 requirements)
require_lws_config(LWS_WITH_TLS 1 requirements)
require_lws_config(USE_WOLFSSL 0 requirements)

if (NOT WIN32)
if (requirements)
	add_executable(${SAMP} minimal-secure-streams.c)

	find_program(VALGRIND "valgrind")

	if (LWS_CTEST_INTERNET_AVAILABLE AND NOT WIN32)

		#
		# External-egress variant: the example's default policy points at
		# warmcat.com, which needs real internet routing.  This is only
		# registered for builds that can actually reach it (dual-stack /
		# IPv4-capable); in an IPv6-only / no-egress CI build the test
		# would hang on DNS / connect until the ctest timeout.  The
		# -local variant below provides the IPv6 coverage instead.
		#
		if (LWS_IPV4)

			#
			# When running in CI, wait for a lease on the resources
			# before starting this test, so the server does not get
			# thousands of simultaneous tls connection attempts
			#
			# sai-resource holds the lease on the resources until
			# the time given in seconds or the sai-resource instance
			# exits, whichever happens first
			#
			# If running under Sai, creates a lock test called "res_sspcmin-stress"
			#

			sai_resource(warmcat_conns 1 40 sspcmin-stress)

			#
			# simple test not via proxy
			#

			if (VALGRIND)
				message("testing via valgrind")
				add_test(NAME ssstress-warmcat COMMAND
					${VALGRIND} --tool=memcheck --leak-check=yes --num-callers=20
					$<TARGET_FILE:lws-minimal-secure-streams-stress> -c 2 --budget 3 --timeout_ms 60000)
			else()
				add_test(NAME ssstress-warmcat COMMAND lws-minimal-secure-streams-stress -c 2 --budget 3 --timeout_ms 50000)
			endif()

			set_tests_properties(ssstress-warmcat
					     PROPERTIES
					     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/minimal-examples-lowlevel/secure-streams/minimal-secure-streams-stress
					     TIMEOUT 300)
			if (DEFINED ENV{SAI_OVN})
				set_tests_properties(ssstress-warmcat PROPERTIES FIXTURES_REQUIRED "res_sspcmin")
			endif()

		endif() # LWS_IPV4 (external-egress variant)

		#
		# Local-server variant: runs against a local
		# lws-minimal-http-server-httpbin over TLS, so it does not need
		# any external network egress.  Suitable for IPv6-only / no-egress CI.
		#

		if (LWS_WITH_SERVER)
			lws_get_free_port(PORT_SS_SRV_TLS)

			configure_file(policy-local.json.in policy-local.json @ONLY)

			add_test(NAME st_ss_hbin
				COMMAND ${CMAKE_SOURCE_DIR}/scripts/ctest-background.sh
					ss_hbin $<TARGET_FILE:lws-minimal-http-server-httpbin>
					-s -p ${PORT_SS_SRV_TLS})
			add_test(NAME ki_ss_hbin
				COMMAND ${CMAKE_SOURCE_DIR}/scripts/ctest-background-kill.sh
					ss_hbin $<TARGET_FILE_NAME:lws-minimal-http-server-httpbin>
					-p ${PORT_SS_SRV_TLS})
			set_tests_properties(st_ss_hbin PROPERTIES
					WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/minimal-examples-lowlevel/http-server/minimal-http-server-tls
					FIXTURES_SETUP ss_hbin
					TIMEOUT 800
					ENVIRONMENT "SAI_LIST_PORT=${PORT_SS_SRV_TLS}")
			set_tests_properties(ki_ss_hbin PROPERTIES FIXTURES_CLEANUP ss_hbin)

			add_test(NAME ssstress-local
				COMMAND lws-minimal-secure-streams-stress
					--policy ${CMAKE_CURRENT_BINARY_DIR}/policy-local.json
					--cpd-bypass
					-c 2 --budget 3 --timeout_ms 50000)
			set_tests_properties(ssstress-local PROPERTIES
					WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/minimal-examples-lowlevel/secure-streams/minimal-secure-streams-stress
					FIXTURES_REQUIRED "ss_hbin"
					TIMEOUT 300)
		endif()

		if (HAS_LWS_WITH_SECURE_STREAMS_PROXY_API OR LWS_WITH_SECURE_STREAMS_PROXY_API)

			#
			# Define test dep to bring up and take down the test
			# proxy
			#

			if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
				# uds abstract namespace for linux
				set(CTEST_SOCKET_PATH "@ctest-sspstress-$ENV{SAI_PROJECT}-$ENV{SAI_OVN}")
			else()
				# filesystem socket for others
                                if (DEFINED ENV{SAI_OVN})
                                        string(SUBSTRING "$ENV{SAI_OVN}" 32 16 SHORT_HASH)
                                else()
                                        set(SHORT_HASH "0")
                                endif()
				set(CTEST_SOCKET_PATH "/tmp/ctest-sspstress-$ENV{SAI_PROJECT}-${SHORT_HASH}")
			endif()
			add_test(NAME st_ssstressproxy COMMAND
				${CMAKE_SOURCE_DIR}/scripts/ctest-background.sh
				ssstressproxy
				$<TARGET_FILE:lws-minimal-secure-streams-proxy>
				-i ${CTEST_SOCKET_PATH} )
			set_tests_properties(st_ssstressproxy PROPERTIES WORKING_DIRECTORY . FIXTURES_SETUP ssstressproxy TIMEOUT 800)

			add_test(NAME ki_ssstressproxy COMMAND
				${CMAKE_SOURCE_DIR}/scripts/ctest-background-kill.sh
				ssstressproxy $<TARGET_FILE:lws-minimal-secure-streams-proxy>
				-i ${CTEST_SOCKET_PATH})
			set_tests_properties(ki_ssstressproxy PROPERTIES FIXTURES_CLEANUP ssstressproxy)

			#
			# the client part that will connect to the proxy
			#

		#	if (VALGRIND)
		#		message("testing via valgrind")
		#		add_test(NAME sspc-minimalstress COMMAND
		#			${VALGRIND} --tool=memcheck --leak-check=yes --num-callers=20
		#			$<TARGET_FILE:lws-minimal-secure-streams-stress-client> -i +${CTEST_SOCKET_PATH} -c 2 --budget 3 --timeout_ms 60000)
		#	else()
				add_test(NAME sspc-minimalstress COMMAND lws-minimal-secure-streams-stress-client -i +${CTEST_SOCKET_PATH} -c 2 --budget 3 --timeout_ms 50000)
		#	endif()

			set(fixlist "ssstressproxy")
			if (DEFINED ENV{SAI_OVN})
				list(APPEND fixlist "res_sspcmin-stress")
			endif()

			set_tests_properties(sspc-minimalstress PROPERTIES
				WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/minimal-examples-lowlevel/secure-streams/minimal-secure-streams-stress
				FIXTURES_REQUIRED "${fixlist}"
				TIMEOUT 300)

		endif()

	endif()

	if (websockets_shared)
		target_link_libraries(${SAMP} websockets_shared ${LIBWEBSOCKETS_DEP_LIBS})
		add_dependencies(${SAMP} websockets_shared)
	else()
		target_link_libraries(${SAMP} websockets ${LIBWEBSOCKETS_DEP_LIBS})
	endif()

	CHECK_C_SOURCE_COMPILES("#include <libwebsockets.h>\nint main(void) {\ni#if defined(LWS_WITH_SECURE_STREAMS_PROXY_API)\n return 0;\n #else\n fail\n #endif\n return 0;\n}\n" HAS_LWS_WITH_SECURE_STREAMS_PROXY_API)

	if (HAS_LWS_WITH_SECURE_STREAMS_PROXY_API OR LWS_WITH_SECURE_STREAMS_PROXY_API)
		add_compile_options(-DLWS_SS_USE_SSPC)

		add_executable(${SAMP}-client minimal-secure-streams.c)
		if (websockets_shared)
			target_link_libraries(${SAMP}-client websockets_shared ${LIBWEBSOCKETS_DEP_LIBS})
			add_dependencies(${SAMP}-client websockets_shared)
		else()
			target_link_libraries(${SAMP}-client websockets ${LIBWEBSOCKETS_DEP_LIBS})
		endif()
	endif()

endif()
endif()
